Excel : trouver plutôt que rechercher avec la fonction TROUVE d’Excel

Lorsqu’on travaille souvent avec Excel, on comprend mieux l’utilité de ses nombreuses fonctions. Découvrez la fonction TROUVE pour faciliter la collecte d’une grande quantité de données.

Guide de démarrage : fonction TROUVE d’Excel

1. Sélectionnez n’importe quelle cellule vide de votre document Excel.
2. Tapez =TROUVE(texte de recherche; texte) en passant comme premier paramètre le texte à rechercher et comme deuxième paramètre la cellule ou le texte dans lequel la recherche doit être effectuée.

Quelle est l’utilité de la formule Excel TROUVE ?

Dans des feuilles de calcul de plusieurs centaines de lignes, il est rapidement difficile de s’y retrouver. Comme tous les autres produits Office, Excel comprend une fonction de recherche intégrée. Pourtant, elle ne trouve pas toujours ce que l’utilisateur recherche. En effet, cette fonction lance automatiquement une recherche dans le document entier.

Pour limiter la recherche à certaines cellules seulement et l’intégrer directement à la feuille de calcul, vous pouvez utiliser la fonction TROUVE.

Combinez-la avec d’autres fonctions pour en exploiter tout le potentiel. Vous pouvez ainsi par exemple afficher certains termes ou extraire certaines parties d’une séquence de caractères.

Excel : syntaxe de la fonction TROUVE

La syntaxe de la fonction TROUVE n’est pas particulièrement complexe. Pour son exécution standard, seuls deux arguments sont nécessaires : que recherchez-vous ? Et où le recherchez-vous ?

=TROUVE(Textederecherche;Texte)

Vous pouvez ajuster votre recherche pour qu’elle commence à partir d’un certain caractère :

=TROUVE(Textederecherche;Texte;[premier_caractère])

Les paramètres dissimulent des données diverses :

• Texte de recherche : il s’agit de la suite de caractères que vous souhaitez rechercher. Vous devez inscrire ce texte entre guillemets. Vous pouvez aussi indiquer une ligne comprenant ce texte.
• Texte : ce paramètre définit le texte dans lequel vous souhaitez procéder à la recherche. Dans la plupart des cas, vous saisirez ici une cellule contenant du texte. Cependant, vous pourrez également saisir directement le texte à cet emplacement. Pour ce faire, vous devrez utiliser des guillemets.
• premier_caractère : dans le cas d’une valeur numérique, veuillez indiquer à partir de quel chiffre commencer la recherche. Cette donnée est facultative.

Excel fournit le résultat sous forme de chiffre. La valeur indique le premier emplacement du texte recherché, c’est-à-dire sa première occurrence en partant de la gauche.

Outre la fonction TROUVE, Excel propose également la fonction TROUVERB. Ces deux fonctions permettent d’obtenir le même résultat et répondent à la même syntaxe. La seule différence réside dans le jeu de caractères utilisable. TROUVE fonctionne avec les jeux de caractères à un octet (SBCS). Parmi eux, on retrouve l’alphabet latin, ainsi que des formes spéciales comme les accents français ou les symboles de ponctuation spécifiques. Cependant, lorsque vous souhaitez utiliser des caractères asiatiques, chinois, japonais et coréens (CJK), il convient d’utiliser la fonction TROUVERB qui fonctionne avec les chaînes de caractères à deux octets (DBCS).

La formule Excel TROUVE en pratique

La formule Excel TROUVE prend tout son sens lorsqu’elle est combinée à d’autres fonctions, révélant ainsi tout son potentiel !

TROUVE & TROUVE : imbrications

Réfléchissons maintenant à la manière de trouver, non pas la première, mais la seconde, troisième ou n-ième occurrence du terme recherché.

=TROUVE(Textederecherche;Texte;TROUVE(Textederecherche;Texte)+1)

L’utilité du troisième paramètre en option peut ainsi être clairement démontrée. Dans cette formule, la formule de recherche de la première occurrence d’un terme est à nouveau saisie en position premier_caractère. Cette valeur « + 1 » indique l’emplacement à partir duquel la fonction ci-dessus doit entamer la recherche. Pour rechercher un troisième emplacement, imbriquez une nouvelle fois la fonction, et ainsi de suite.

TROUVE & ESTNUM : fonctions VRAI

La fonction TROUVE d’Excel permet l’énoncé d’une fonction VRAI à partir des informations d’emplacement : le terme recherché est-il disponible dans le texte ?

=ESTNUM(TROUVE("Peluche";B2))

La fonction ESTNUM renvoie la valeur VRAI lorsque le résultat de la fonction TROUVE est un chiffre. Dans le cas contraire, la valeur FAUX s’affiche. Dans la mesure où la fonction TROUVE d’Excel indique l’emplacement du terme sous forme de nombre entier, la fonction ESTNUM peut y réagir. Lorsque le terme recherché n’est pas contenu dans le texte, la fonction TROUVE renvoie un message d’erreur non numérique et ESTNUM affiche la valeur FAUX.

Il peut également être intéressant de voir où les termes recherchés apparaissent dans le fichier. Cela est possible lorsque les données sont réparties dans plusieurs cellules, par exemple dans une liste de vente. La formule peut ainsi être ajoutée, comme toutes les autres formules, au formatage conditionnel. Vous pouvez ainsi marquer toutes les commandes en lien avec des oursons.

TROUVE & STEXT : extraction de caractères

Les désignations d’articles peuvent être très longues et obscures, c’est pourquoi il se peut que vous souhaitiez parfois extraire certaines parties d’une chaîne de caractères. À cet effet, Excel prévoit trois fonctions : GAUCHE, DROITE et STEXT. Intéressantes séparément, leur combinaison avec la fonction TROUVE optimise les performances de ces formules. Nous partons du principe que vos désignations suivent un modèle prédéfini et sont composées de lettres, chiffres et traits d’union : ABCDE-A-12345-T. Vous souhaitez en extraire la partie numérique centrale.

Dans la mesure où cette chaîne de caractères n’a pas de longueur déterminée, vous ne pouvez pas l’extraire au moyen de fonctions simples. Ces dernières recherchent un nombre de caractères défini que vous ne pouvez pas garantir d’emblée. Grâce aux traits d’union, la fonction TROUVE peut toutefois vous aider, car elle est en mesure de vous ramener aux emplacements recherchés.

Comme vos chaînes de caractères comptent plusieurs traits d’union, vous devez imbriquer la fonction TROUVE. Dans l’exemple ci-après, nous partons du principe que la partie numérique à extraire compte toujours cinq caractères.

=STXT(A2;TROUVE("-"; A2;TROUVE("-"; A2;TROUVE("-";A2)+1))+1;5)

Si leur longueur ne peut pas être définie, il est également possible d’imbriquer plusieurs fonctions TROUVE. Dans la mesure où la chaîne de caractères recherchée se termine par un trait d’union, vous pouvez limiter la recherche à ce caractère et déterminer ainsi la longueur de la partie à extraire.

=STXT(A2;TROUVE("-";A2;TROUVE("-";A2;TROUVE("-";A2)+1))+1; TROUVE("-";A2;TROUVE("-";A2;TROUVE("-";A2)+1)+1)-TROUVE("-";A2;TROUVE("-";A2;TROUVE("-";A2)-1))-3)

Cette formule est certes très obscure, cependant, elle atteint bien votre objectif. Quel que soit le nombre de caractères placé entre deux traits d’union, Excel extraira toujours les caractères souhaités à l’aide de la formule TROUVE.

TROUVE & SI : Si-Alors-Sinon

La fonction TROUVE se combine très bien avec la fonction SI. Vous souhaitez exécuter une action lorsqu’une séquence de caractères définie apparaît dans une cellule ? La combinaison des fonctions SI et TROUVE vous le permet : si la séquence de caractères est trouvée, alors il se passe ceci, sinon il se passe cela. Le seul problème est que, lorsque la séquence de caractères n’apparaît pas, la fonction TROUVE affiche une erreur. C’est pourquoi la fonction ESTERREUR doit également être activée.

=SI(ESTERREUR(TROUVE("Peluche";A2));"Non";"Oui")

Lorsque la fonction TROUVE ne trouve pas le terme recherché (« Peluche » dans l’exemple présent), elle affiche un message d’erreur. La condition de la fonction ESTERREUR est alors remplie et la fonction SI active la première option : non, le terme recherché n’apparaît pas. À l’inverse, lorsque la fonction TROUVE trouve le texte recherché, elle indique un nombre qui ne satisfait pas la condition de la fonction ESTERREUR. L’alternative est donc la suivante : oui, le terme recherché apparaît.